Notifications
Clear all

Contar sequências de números e de espaços em branco numa linha  

  RSS

Wagner Paulo
(@wagner-paulo)
New Member
Entrou: 2 meses atrás
Posts: 4
27/07/2020 3:08 pm  

Olá,

Tenho uma tabela com 25 colunas e milhares de linhas com caracteres numéricos. Gostaria de uma fórmula para contar as sequências de números, bem como de espaços, conforme modelo anexo. 


ResponderCitar (Quote)
deciog
(@deciog)
Prominent Member
Entrou: 5 anos atrás
Posts: 772
29/07/2020 8:00 am  

 Wagner Paulo, Bom Dia.

 

Na célula AC2 coloca esta formula, copia para baixo e para direita

=NÚM.CARACT(ARRUMAR(EXT.TEXTO(SUBSTITUIR(" "&ARRUMAR(CONCAT(SE($C2:$AA2<>"";1;" ")));" ";REPT(" ";30));30*COLS($A$1:A$1);30)))

 Formatar celula com 0;-0;;@ para não mostrar zeros

Na célula AP2 coloca esta formula, copia para baixo e para direita

=NÚM.CARACT(ARRUMAR(EXT.TEXTO(SUBSTITUIR(" "&ARRUMAR(CONCAT(SE($C2:$AA2="";1;" ")));" ";REPT(" ";30));30*COLS($A$1:A$1);30)))

Formatar celula com 0;-0;;@ para não mostrar zeros

 

Outra forma

Na célula AC2 coloca esta formula, copia para baixo e para direita

=SEERRO(FILTROXML("<a><b>"&UNIRTEXTO("</b><b>";;TEXTO(FREQÜÊNCIA(SE($C2:$AA2<>"";$C$1:$AA$1);SE($C2:$AA2="";$C$1:$AA$1));"0;;;"))&"</b></a>";"//b["&COL(A1)&"]");"")

 

Na célula AP2 coloca esta formula, copia para baixo e para direita

=SEERRO(FILTROXML("<a><b>"&UNIRTEXTO("</b><b>";;TEXTO(FREQÜÊNCIA(SE($C2:$AA2="";$C$1:$AA$1);SE($C2:$AA2<>"";$C$1:$AA$1));"0;;;"))&"</b></a>";"//b["&COL(A1)&"]");"")

 

Tive ajuda dos universitários

 

Confere se é desta forma que desejas

 

Se foi útil, clique na mãozinha Curtir é uma forma de agradecimento

Decio

 

 

Marque o tópico como Resolvido se foi solucionado seu problema.
Brasil, São Paulo - SP
Décio Gassi


ResponderCitar (Quote)
Wagner Paulo
(@wagner-paulo)
New Member
Entrou: 2 meses atrás
Posts: 4
13/08/2020 12:37 pm  

As fórmulas acimas não funcionaram no Excel instalado no meu PC que é o 2010. Mas ao entrar no Excel 365 online, as duas primeiras fórmulas funcionaram perfeitamente, já as duas últimas não.


ResponderCitar (Quote)
Wagner Paulo
(@wagner-paulo)
New Member
Entrou: 2 meses atrás
Posts: 4
13/08/2020 12:39 pm  

De qualquer forma, muito obrigado pela atenção dispensada 


ResponderCitar (Quote)
Wagner Paulo
(@wagner-paulo)
New Member
Entrou: 2 meses atrás
Posts: 4
13/08/2020 12:39 pm  

De qualquer forma, muito obrigado pela atenção dispensada 


ResponderCitar (Quote)
deciog
(@deciog)
Prominent Member
Entrou: 5 anos atrás
Posts: 772
13/08/2020 12:45 pm  

@wagner-paulo, Boa Tarde

 

Notei que não agradeceu a ajuda dada

Para a sua versão 2010 encerrar com CTRL+SHIFT+ENTER

Sobre Excel On-Line essa formula não irão funcionar talvez desta forma ou também teclar CTRL+SHIFT+ENTER ou

=IFERROR(FILTERXML("<a><b>"&TEXTJOIN("</b><b>",,TEXT(FREQUENCY(IF($C2:$AA2<>"",$C$1:$AA$1),IF($C2:$AA2="",$C$1:$AA$1)),"0;;;"))&"</b></a>","//b["&COLUMN(A1)&"]"),"")

e

=IFERROR(FILTERXML("<a><b>"&TEXTJOIN("</b><b>",,TEXT(FREQUENCY(IF($C2:$AA2="",$C$1:$AA$1),IF($C2:$AA2<>"",$C$1:$AA$1)),"0;;;"))&"</b></a>","//b["&COLUMN(A1)&"]"),"")

 

Se foi útil, clique na mãozinha Curtir é uma forma de agradecimento

Decio

Marque o tópico como Resolvido se foi solucionado seu problema.
Brasil, São Paulo - SP
Décio Gassi


ResponderCitar (Quote)
Compartilhar: