Use o gerenciador de nomes (Ctrl + F3) e nomeie o intervalo, no caso, o range A2:A400. Coloque um nome significativo, digamos "VALOR_TOTAL"

Isso vai fazer com que o range do intervalo mude automaticamente, caso a coluna seja reposicionada.

Agora, é só referenciar pelo nome que vc criou.

Em vez de usar algo como:
Range("A2:A400").Locked = true

Use:
Range("VALOR_TOTAL").Locked = true

Abs

Apenas outra alternativa:

Sub Macro1()

ActiveSheet.Unprotect ("123")

Cells.Locked = False

icol = 1
col = Range("Z1").End(xlToLeft).Column 'Supondo que Z seja suficiente.

Do While icol <= col
If Cells(1, icol) = "VALOR ATUAL" Then
Columns(icol).Locked = True
icol = icol + 1
Else
icol = icol + 1
End If
Loop

ActiveSheet.Protect ("123")

End Sub

Minha sugestão é simplesmente utilizar a ferramenta de VALIDAÇÃO DE DADOS. Selecione as linhas 2:400, vá no menu DADOS e no botão "VALIDAÇÃO DE DADOS", então selecione na lista permitir a opção "PERSONALIZADO" e no campo de fórmulas digite a fórmula: =A$1<>"VALOR ATUAL". Se quiser configure uma mensagem na aba alerta de erros e Pronto. Solução direta sem precisar ficar criando códigos em VBA.

Veja modelo anexo.

Abraços!

Por falta de sugestões este tópico não vai deixar de ser resolvido.
Segue mais uma opção com VBA :

Sub BloqueiaColsCriterio()
Dim lgTtColunas As Long
Dim iCol As Long
Dim myCol As String

    ActiveSheet.Unprotect ("SuaSenha")
    
    Cells.Locked = False
    
    'Conta as colunas preenchidas
    lgTtColunas = Cells(1, Columns.Count).End(xlToLeft).Column
    
    For iCol = 1 To lgTtColunas
        
        'Condição
        If Cells(1, iCol).Value = "VALOR ATUAL" Then
         
         myCol = GetColumnLetter(iCol)
         
         Range(myCol & "2:" & myCol & "400").Locked = True
        
        End If
        
    Next iCol

    ActiveSheet.Protect ("SuaSenha")

End Sub

Function GetColumnLetter(colNum As Long) As String
    Dim vArr
    vArr = Split(Cells(1, colNum).Address(True, False), "$")
    GetColumnLetter = vArr(0)
End Function

REALMENTE, não será por falta de opções. Considerei todas as respostas e segui os passos do MAURO COUTINHO que me pareceU mais adequada. Eu gostaria de abusar da generosidade um pouco mais. É o seguinte, na minha planilha eu terei outras colunas com o texto VALOR ATUAL, como disse no posto, mas elas acabam se diferenciando com o ano, ou seja, vão existir "VALOR ATUAL 2014", "VALOR ATUAL 2015", "VALOR ATUAL 2016"...como ficaria a macro para fazer o bloqueio das colunas pela parte do título, no caso, "VALOR ATUAL" ?.

Resumindo, bloquio de todas as colunas que contenham no título a parte do texto "VALOR ATUAL..." !

Na Macro do Mauro, modifique a linha de 'Condição para:

If Mid(Cells(1, iCol).Value, 1, 11) = "VALOR ATUAL" Then

A adequação desta situação para a minha proposta de solução através de validação de dados é alterar a fórmula da validação para:

=CONT.SE(A$1:A$1;"*VALOR ATUAL*")=0

Abraços!

Obrigado a todos.Ficou muito boa a solução.

Valeu mesmo.