Não entendi, que formatação??

Não entendi, que formatação??

A formatação de negrito da fonte.
Por exemplo, o texto da coluna A estaria em negrito, e o das colunas B, C e D não. Eu gostaria de colocar todos os textos das colunas A, B, C e D na coluna E.
Como E=A&B&C&D, porém a célula E deve ficar com o texto misto entre negrito e normal.
Não sei se expliquei bem.

Bom dia!!

Poste seu arquivo modelo compactado, com o resultado feito manualmente.

Att

Bom dia!!

Poste seu arquivo modelo compactado, com o resultado feito manualmente.

Att

Está no arquivo anexo, zipado conforme a recomendação.

Que eu saiba, por formulas não dá; porem algo parecido foi discutido em ExcelBr (yahoogroups);de uma olhada em : http://br.groups.yahoo.com/group/ExcelBr/message/78499 e/ou http://br.groups.yahoo.com/group/ExcelBr/message/77770
Talvez possa auxilia-lo

Obrigado Reinaldo, não tinha encontrado estes posts na minha pesquisa. Acho que com eles eu já consigo evoluir um pouco, vou tentar seguir aquela linha de trabalho. Criar um padrão para formatar a nova célula que contém todos os dados e esquecer a formatação das células antigas.

Bom dia!!

Talvez isso ajude.

Sub test_AleVBA()
    Dim cell   As Range
    Application.ScreenUpdating = False
    For Each cell In Range("A2", Range("A" & Rows.Count).End(xlUp))
        Call concatenar_celulas(cell.Offset(, 4), cell.Resize(, 4)) 'Destination column A, Source B:F
    Next cell
    Application.ScreenUpdating = True
End Sub

Sub concatenar_celulas(cell As Range, source As Range)

    Dim c      As Range
    Dim i      As Integer

    i = 1

    With cell
    
        .Value = vbNullString
        .ClearFormats

        For Each c In source
            If Len(c.Value) Then .Value = .Value & "/" & Trim(c)
        Next c
        
        .Value = Trim(Mid(.Value, 2))

        For Each c In source
        
            With .Characters(Start:=i, Length:=Len(Trim(c))).Font
                .Name = c.Font.Name
                .FontStyle = c.Font.FontStyle
                .Size = c.Font.Size
                .Strikethrough = c.Font.Strikethrough
                .Superscript = c.Font.Superscript
                .Subscript = c.Font.Subscript
                .OutlineFont = c.Font.OutlineFont
                .Shadow = c.Font.Shadow
                .Underline = c.Font.Underline
                .ColorIndex = c.Font.ColorIndex
            End With
            
            .Characters(Start:=i + Len(c) + 1, Length:=1).Font.Size = 1
            i = i + Len(Trim(c)) + 1

        Next c

    End With

End Sub

Alexandrevba,
muito obrigado, funcionou perfeitamente aqui.
Vou estudar o código e adaptá-lo na minha planilha.
Novamente obrigado!