https://www.youtube.com/results?search_query=vba+exportar+txt

Amigo, aqui onde estou não tenho acesso ao youtube. Mas vlw.

Segue uma possibilidade

Sub ExportColum()
Dim Caminho As String, Arquivo As String
Dim X As Integer, W As Integer, Linha As Integer
'Determina o diretorio a ser utilizado, neste caso mesmo diretorio da planilha
Caminho = ThisWorkbook.Path & Application.PathSeparator
For X = 1 To Sheets().Count
    If Sheets(X).Name <> "GERAL" Then
        Arquivo = Sheets(X).Name & ".txt"
        Open Caminho & Arquivo For Output As #1
        'Determina a ultima coluna com dados
        W = Sheets(X).Cells(4, Cells.Columns.Count).End(xlToLeft).Column
        For Linha = 5 To Sheets(X).Cells(Cells.Rows.Count, W).End(xlUp).Row
            Print #1, Sheets(X).Cells(Linha, W).Value
        Next
    Close #1
    End If
Next
End Sub

Segue mais uma opção:

Sub Exoprta_Abas_Coluna_R()
    Dim varSheet As Variant, nAbas As Variant
    Dim Linha As Long
    Dim Arq_Texto As String, nArqTXT As Integer
    Dim ShtCONSOLIDADO As Worksheet
    Dim wb As Workbook
    Set wb = ThisWorkbook
    
    'Por cada sheet no workbook
    For Each varSheet In Sheets
        'Captura o nome de cada aba
        nAbas = varSheet.Name
        
        'Ignora e pula a Aba GERAL
        If nAbas <> "GERAL" Then
            'Define a planilha
            Set ShtCONSOLIDADO = wb.Sheets(nAbas)
                            
            'Local e nome do arquivo texto
            'Ajuste o local que quer salvar o arq texto
            Arq_Texto = "C:Documents" & nAbas & ".txt"
            
            'numeração do arquivo contagem
            nArqTXT = FreeFile
            'Abre o arquivo para escrita
            Open Arq_Texto For Output As nArqTXT
                    'Verifica a qde de linhas
                    Linha = ShtCONSOLIDADO.Range("R5").End(xlDown).Row
                    
                    'define o range a ser exportado
                    Set sRG = ShtCONSOLIDADO.Range("R5:" & "R" & Linha)
                    
                    'Copia para o arq texto criado
                    For Each L In sRG.Rows
                        For Each C In L.Columns
                            Print #nArqTXT, C.Value; vbTab; ' escreve o valor da celula + uma tabulação
                        Next
                        Print #nArqTXT, ' nova linha
                    Next
        'Fecha o arquivo e inicia o outro
        Close nArqTXT
        MsgBox "Exportação da Aba :- " & nAbas & " - concluída com Sucesso"
        End If
    Next

End Sub

[]s