Compacte seu modelo e publique para facilitar a ajuda...

*Eu criei um código para adiantar, e funcionou.

Sub InserirCOmentario()
Dim rngSelecao  As Range
Dim rngCelula   As Range
On Error Resume Next

    Set rngSelecao = Selection.CurrentRegion
    If rngSelecao.Columns.Count = 2 Then
        For Each rngCelula In rngSelecao
            If rngCelula.Column = rngSelecao.Cells(1).Column Then
                With rngCelula
                    .Comment.Delete
                    .AddComment
                    With .Comment
                        .Visible = False
                        .Text Text:=rngCelula.Offset(0, 1).Value
                    End With
                End With
            End If
        Next rngCelula
    Else
        MsgBox "Selecionar intervalo com 2 colunas"
    End If
    Set rngSelecao = Nothing

End Sub

Muito obrigado mesmo e desculpa minha falta de experiencia. Tenho que me aprofundar para poder começar a ajudar outros.
Estou enviando uma versão compacta da planilha. No caso tudo o que tiver na coluna "P" precisa virar um comentário na coluna "O" para que eu possa limpar a coluna P e dar um visual melhorado para a planilha.
Muito obrigado novamente.

fiz uma macro que verifica qual a ultima linha da colupa P
se tiver algum valor vai pegar esse valor adicionar como comentario na celula da coluna O mesma linha
e apagar o conteudo da coluna P
se caso queira trocar o comentrio é só escrever oq quer na coluna P e rodar novamente a macro que o comentario da coluna O mesma linha vai ser substituido

caso não queira que o conteudo da coluna p seja apagado é só tirar essa linha

Cells(L, "P").Value2 = ""

Sub Valor_como_comentario2()

    Dim celts As Range
    LF = Cells(Rows.Count, "P").End(xlUp).Row    'determina a ultima linha com dados da coluna P
    For L = 2 To LF
        Valc = Cells(L, "P").Value2

        If Valc <> "" Then
            Set celts = Range("O" & L)

            If Not celts.Comment Is Nothing Then celts.Comment.Delete

            celts.AddComment
            celts.Comment.Visible = False
            celts.Comment.Text Text:=Valc
            Cells(L, "P").Value2 = ""

        End If
    Next
End Sub

antes que me chamem atenção

Sub Valor_como_comentario2()
    Dim L As Long, Valc As String
    Dim CellTs As Range
    For L = 2 To Cells(Rows.Count, "P").End(xlUp).Row
        Valc = Cells(L, "P").Value2
        If Valc <> "" Then
            With Cells(L, "O")
                If Not .Comment Is Nothing Then .Comment.Delete
                .AddComment
                .Comment.Visible = False
                .Comment.Text Text:=Valc
                Cells(L, "P").Value2 = ""
            End With
        End If
    Next
End Sub

Rod, quando eu disse: compacte seu arquivo, eu quis dizer: compacte seu arquivo. O fiz para vc, em formato RAR, e segue a regra do forum que justifica o comportamento:

Regras do forum:

• Upload
Devido a ultrapassagem da marca de 1,5Gb de armazenamento de arquivos na hospedagem do Planilhando, limitaremos o tamanho de cada arquivo para 2Mb sendo obrigatório o uso dos formatos .zip - .rar - .ice visto a gratuidade e não geração de recursos para bancar o site.

Assim sendo, todos os anexos deste tópico foram compactados.

Por favor leia as regras (link na minha assinatura), e passe a compactar todos os seus anexos.

Obrigado,

Fernando

Inclui o código por mim sugerido no seu arquivo e funcionou assim:

- Vc abre seu arquivo, seleciona o intervalo de O a P, somente as células preenchidas e aonde vc quer que rode a inserção dos comentários. Se vc selecionar a coluna inteira, vai demorar uma eternidade
- Alt+F11
- Encontre o módulo, duploclique nele
- Com o cursor em qquer parte do código, tecle F5

Pronto,