Em resumo o codigo faz o que ou deveria fazer o que?

Qto as limitações que vc precisa acho que uns ifs bem colocados resolveria por exemplo:

Vc pode usar algo assim apos a soma

if Valor da soma >= que valor indicado por vc then exit sub

ou seja qdo a soma atingir o valor indicado por vc ela para de executar o codigo.

Existem outras maneira de fazer isso mas no seu caso essa é a mais simples.

Então não consigo fazer ela gerar uma nova sequencia de números sozinha, tenho que ficar rodando manualmente, gostaria que ela rodasse uma nova sequencia de números quando por exemplo na planilha1 o valor da célula C3 ( que é a soma dos números gerados pela macro ) fosse igual ou maior que o valor da célula C2 que é colocado manualmente, quando este valor é atingido ela para de gerar nova sequencia de números e só retorna ao apertar o botão, eu não consegui montar esta macro de jeito nenhum.
Será que alguém consegue montar isso?
É uma planilha para teste de um leitor de código, e eu não conheço quase nada de excel minha área de atuação é automação de máquinas e necessito que o leitor fique lendo este código até atingir o valor, basicamente é isso, eu não sei como fazer isso, tudo o que está ai até agora fui pegando na net e montando, gostaria de saber se alguém pode me ajudar a montar isso?

Deixa eu ver se entendi vc quer que o codigo rode infinitamente e reinicie, ou seja limpe toda a informação da coluna B e começe registrar novamente ate atingir determinado valor?

É isso?

Isso o código vai rodar infinitamente limpando como você disse a coluna B e gerando um novo código, até atingir um valor na por exemplo célula C3 que seja igual ou mair que o valor da célula C2, o valor de C2 é colocado manualmente e o valor de C3 é a somatória dos valores gerados na coluna D pela planilha e não pelo código, ai ela para de gerar um novo valor na coluna B até apertar um botão de reiniciar, caso este valor nunca seja atingido tenho que ter uma forma de parar, pode ser pro um outro botão ou um contador sei lá de 100.000.000 de códigos ai ela para, e fica aguardando apertar o botão.
Não sei se consegui explicar direito.

Atribua esse botão pra interromper para essa sub "Interromper()"
E rode a macro.
Agora é só fazer o que quer que faça

Dim abortar As Boolean

Sub GerarNumerosAleatoriosSemRepeticao()
Dim i                           As Long
Dim j                           As Long
Dim bRandomOk                   As Boolean
Dim valor_aleatorio             As Long
Dim valor_maior                 As Long
Dim total_numeros_gerados       As Long
Dim total_numeros_para_gerar    As Long
Dim iControleGerar              As Long
Dim iColunaCelula               As Long

    Do
    Range("B2:B21").ClearContents

    valor_maior = 60    'Informe o maior número que poderá ser gerado
    total_numeros_para_gerar = 20      'Informe a quantidade de números aleatórios que deseja gerar
    total_numeros_gerados = 0
    iLinhaCelulaInicial = 2     'Informe a linha da primeira célula que será escrito o número
    iColunaCelula = 2   'Informe a coluna. Exemplo: Coluna B = 2
    iControleGerar = total_numeros_para_gerar + iLinhaCelulaInicial - 1
    
    'Gera quantos números forem indicados na variável 'total_numeros_gerados'
        For i = iLinhaCelulaInicial To iControleGerar
            total_numeros_gerados = total_numeros_gerados + 1
        
            'Fica executando a geração de um novo número enquanto houver duplicidade
            Do
                'Utilize a condição abaixo para verificar se ainda existem números possíveis a serem gerados
                    'Porque se i for maior que o valor limite, significa que todos os números já saíram. Então, sai do loop
                If valor_maior < total_numeros_gerados Then
                    valor_aleatorio = 0
                    bRandomOk = True
                    Exit Do
                End If
        
                'Gera um novo número
                Randomize   'Sempre utilize esta função antes de chamar Rnd
                valor_aleatorio = Int((valor_maior * Rnd) + 1)
                bRandomOk = True
        
                'Verifica se já saiu este número
                For j = iLinhaCelulaInicial To i
                    If Cells(j, iColunaCelula).Value = valor_aleatorio Then
                        bRandomOk = False
                        Exit For
                    End If
                Next j
        
            Loop While bRandomOk = False
        
            'Escreve o número na célula
            Cells(i, iColunaCelula).Value = valor_aleatorio
        Next i
        
        If Range("C3").Value >= Range("C2").Value Then Exit Do
        DoEvents
        If abortar = True Then abortar = False: GoTo abortando
        
    Loop

    MsgBox "valor encontrado", vbInformation
    Exit Sub
abortando:
    MsgBox "operação abortada", vbInformation

End Sub

Sub Interromper()
    abortar = True
End Sub

Qualquer coisa da o grito.
Abraço

Muito obrigado está funcionando exatamente como eu queria.

Pessoal a macro ficou tão boa que o meu leitor não consegue ler os códigos, a geração está muito rápida, tem como fazer ela demorar um pouco mais, coisa de 1 segundo ou menos?

Tenta colocar isso logo após o "Do" (brm no início)

Application.Wait TimeSerial(hour(now()), minute(now()), second(now()) + 1)

Qualquer coisa da o grito.
Abraço

Bernardo, muito, mais muito obrigado mesmo, ficou perfeita,não tenho como agradecer.
Já estou conseguindo fazer os testes dos leitores e deu tudo certo.