A fórmula de Média já vai excluir todos os valores iguais a 0.
Mas, acho que você quer que a quinta e a sexta sejam contadas também na média, é isso? Não ficou claro.
Existe no 2007 também a função MédiaSE que também não sei se atende ao que você pretende.

Meu nobre professor mineiro...

deixa ver me me expresso melhor:

*Na coluna D quando não houver produção será branco " "
**Eu já tenho a média numa celula abaixo ex. D30

1º Preciso calcular quanto dias tenho a produzir ( excluindo o sab. e dom) contando de hoje, ou seja ">="&hoje. ex. 7 dias ainda vou produzir no mês.

2º achando esses nº de dias ai eu multiplico péla média de produção e encontro meu estoque projetado.

Col A----------------Col B---------------- Col C---------------- Col D----------------
Data----------------DIA----------------Prod. prevista------------Prod. Realizada

01/07------------- QUA----------------10.000-------------------------8.000
02/07------------- QUI----------------10.000-------------------------7.300
03/07------------- SEX----------------10.000-------------------------6.800
04/07------------- SAB---------------- -------------------------
05/07------------- DOM---------------- -------------------------
06/07------------- SEG-----------------10.00--------------------------6.500

Media 7.150

Porque mineiro??? rs. Além disso, sou meninaaaa
Desculpe se não consegui lhe entender. Às vezes é difícil sintonizar as idéias, né.
No final de tudo, o que compreendi é que você precisa é saber de hoje até o final deste mês, quantos dias úteis você tem ainda a produzir.
Se for isso, você pode usar a fórmula:
=DIATRABALHOTOTAL(HOJE();FIMMÊS(HOJE();0))
Se precisar usar como referência um outro dia, como os da coluna A, é só substituir "HOJE()" pela referência (A10, por exemplo, mas que neste caso deveria estar também com o ano pra ficar mais certinho).
Essa função "Diatrabalhototal" retorna ao usuário a quantidade de dias úteis entre uma data inicial e uma data final.
Ficará ainda mais correta se você tiver uma listinha de feriados (a qual você incluísse até seus feriados municipais) - um parâmetro adicional (e não obrigatório) que você pode incluir na fórmula.
Supondo que você tivesse essa listinha de A1 a A10, a fórmula ficaria:
=DIATRABALHOTOTAL(HOJE();FIMMÊS(HOJE();0);A1:A10)
Já "Fimmês" mostra pra você o último dia do mês com base em uma data e em quantos meses pra frente você quer ver. Por isso coloquei aquele zero (porque não quero ver nenhum mês pra frente).

Agora acertei?

Oi Val....... me desculpa ......

Xou de bola.......Funcionou.....

Se vc me permitir tenho mais coisa a aprender.

Tenho duas linhas de produções

1º de seg a sex - essa formula me atende.

2º de seg a sab - como ficaria essa formula ?

Tem como agregar mais funções para contar os sábado, mas e se Sábado for um feriado? Deve contar também como dia útil?

Se o sábado for feriado não é para contar.

Os feriados também não são para contar.

Ex. 12/07 - foi feriado aqui em Recife
12/10 - Também é feriado em Recife ( eu teria que abater esse dia)

Testa essa aqui então:
=DIAS360(HOJE();FIMMÊS(HOJE();0);VERDADEIRO)-(INT(DIAS360(HOJE();FIMMÊS(HOJE();0);VERDADEIRO)/7)+SE(DIA.DA.SEMANA(HOJE())=1;1;0))-(CONT.SES(N4:N5;">="&HOJE();N4:N5;"<="&FIMMÊS(HOJE();0)))
A fórmula DIAS360 retorna a quantidade de dias entre duas datas.
Assim, temos a quantidade cheia de dias.
Na segunda parte, excluímos a quantidade de domingos. Para isso, fazemos novamente o intervalo entre duas datas e dividimos por 7.
Pegamos o número inteiro (sem decimais) desta divisão (INT) e ainda verificamos se HOJE() for domingo, acrescentamos +1 na fórmula (porque se não, não dá certo porque DIAS360 não conta o dia inicial -então, se este for um domingo, nem será contado).
Com Cont.Ses, eu verifico se o intervalo de feriados (que no exemplo está entre N4 e N5) contém datas maiores ou iguais a hoje e/ou datas menores ou inferiores ao fim do mês.

Lembre-se que se você quiser que seja contado também o dia inicial, deve somar +1 no final da fórmula.

Val, bom dia.
Muito obrigado pela força.

Ontem meu dia foi dificil, hoje vou aprender realmente a formula abaixo (só ctrl c + ctr v não vale) depois vou aprender a usar a segunda formula, a sua última postagem ainda não tive coragem de estudar.

=DIATRABALHOTOTAL(HOJE();FIMMÊS(HOJE();0))

=DIATRABALHOTOTAL(HOJE();FIMMÊS(HOJE();0);A1:A10)

Vc é fera.....

Imagina! Parabéns pela inicitiva em aprender.
Eu também estou aprendendo sempre.
Precisando, estamos ai!

Tenho mais uma necessidade nessa planilha.

Col A...........................Col B
DIA...........................Qtdade Planejada
23/07/10.......................10.000
24/07/10........................20.000
25/07/10........................15.000
26/07/10........................25.000
27/07/10........................ " " em branco ( o zero mexe na média)
28/07/10........................" " em branco
29/07/10........................" " em branco
30/07/10........................10.000
1º Critério: Contar na Col B o que for <> de " " branco
2º Critério: usar o ">="&hoje para realizar o crítério acima.
Nesse exemplo a resposta seria 5, essa quantidade de dias será importante nas projeções de produções para que a fábrica faça ou não hora extra.

Olá, tudo bem?
Pelo que entendi você quer fazer uma média ignorando o 0 (Zero), pois interfere no cálculo da média por o zero ser um termo.

Use matriz para tal tarefa

Média Ignorando o 0 (Zero):
{=MÉDIA(SE(B3:B10<>0;B3:B10))}

Para a média dos valores que a data seja superior a data atual HOJE(), sem ignorar o 0 (zero):
{=MÉDIA(SE(A3:A10>HOJE();B3:B10))}

Agora juntando os dois critérios, ou seja, a média dos dados que possuem data superior a data atual >HOJE() e que contém valores maiores que 0 (Zero):

{=MÉDIA(SE((A3:A10>HOJE())*(B3:B10>0);B3:B10))}

Observações:
1 - A coluna A contém as datas;
2 - A coluna B contém os valores.
3 - Por se tratar de uma fórmula matricial, não é necessário digitar as chaves {}, bastando ao término da edição da fórmula, teclar a combinação de teclas CTLR+SHIFT+ENTER.

Explicitei de 3 maneiras diferentes, sendo a última, a solução completa extraindo toda a média com os critérios em apenas uma célula.

Luthius

Abraço

Luthius, show de bola tua explicação e as formulas.

eu ainda preciso de outra informação que está na COL B.

note que existem dias em que tem quantidade programada e outros com " " branco, preciso saber a quantidades de dias em que tem produção programada, porém usando o critério de ">="&hoje().

Dessa forma tenho a quantidade de dias que ainda vou produzir.

Já que começamos a falar de matriz, vamos manter o mesmo assunto. Rs

{=SOMA((A3:A10>HOJE())*(B3:B10<>""))}

Explicação:
Toda a data programada que for maior do que a data atual a fórmula irá contar.

Abraço

VALEU !!!!!!!

FICOU NOTA 10