Bom dia mascosuke,

Tenta assim:

=somarproduto(--(étexto(A1:A10));--(núm.caract(A1:A10)>1))

Qualquer coisa da o grito.
Abraço

Tentou usar um CONT.SES?

=CONT.SES(B:B;"<>"&0;B:B;"<>")

Pietro, pelo que eu entendi ele quer que conte apenas nomes e ignore números, zeros e células em branco.

Dá para fazer com o cont.ses() também, mas não da forma como colocou. Para essa solução, eu preferiria utilizar o somarproduto().

Qualquer coisa da o grito.
Abraço

Bernardo

Muito bom amigo! Funcionou!

Poderia me explicar a lógica dessa formula? Gostaria de aprender utilizá-la.

Bom dia marcosuke,

A fórmula somarproduto() é uma fórmula matricial onde eu utilizo o "--" antes de cada condição como booleano que será multiplicada as condições e depois somado o total.

Resumindo. Supondo que somente as células de A1 a A10 esteja preenchido como:
A1= TESTE
A2= BERNARDO
A3= A
A4= MARCOS
A5 em diante vazio ou zeros...

=somarproduto(--(étexto(A1:A10));--(núm.caract(A1:A10)>1))

étexto(A1:A10) vai verificar cada célula se está preenchida como texto e retornar:
{VERDADEIRO;VERDADEIRO;VERDADEIRO;VERDADEIRO;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO}

--(étexto(A1:A10)) já utiliza o booleano trata a informação acima retornando:
{1;1;1;1;0;0;0;0;0;0}
Ou seja, "VERDADEIRO" = 1 e "FALSO" = 0

Como você disse "nomes", eu desconheço nome de uma letra, então coloque para verificar a quantidade de caracteres em cada célula devendo ter mais de um caractere.

núm.caract(A1:A10)>1 vai verificar cada célula se tem mais de um caractere e retornar:
{VERDADEIRO;VERDADEIRO;FALSO;VERDADEIRO;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO}

--(núm.caract(A1:A10)>1) já utiliza o booleano trata a informação acima retornando:
{1;1;0;1;0;0;0;0;0;0}

Retornamos então a fórmula:
=SOMARPRODUTO({1;1;1;1;0;0;0;0;0;0};{1;1;0;1;0;0;0;0;0;0}) Onde ele fará o produto das duas ranges e depois somar

{1;1;1;1;0;0;0;0;0;0}
{1;1;0;1;0;0;0;0;0;0}
{1;1;0;1;0;0;0;0;0;0} Somando esse intervalo, teremos o resultado 3.

Essa seria tipo uma explicação analítica da fórmula. É tipo o que um "Avaliar fórmula" faz (ferramenta nativa do Excel).

Não sei se expliquei muito bem mas é tipo isso.

Qualquer coisa da o grito.
Abraço

Bernardo
Ótima explicação!

Amigo, muito obrigado pela disposição e boa vontade em ajudar!