Bom dia emipejota

Seja bem vindo ao fórum!

Se você disse que quer somar com critérios poderá, então poderá usar as funções SOMASES ou SOMARPRODUTO.

Uma observação,você descreveu que a coluna 2 não tem valores e sim quantidades, então, vc não irá somar e sim contar.

Para contar utiliza-se as funções CONT.SES ou SOMARPRODUTO.

Para facilitar, anexa um exemplo da tua planilha compactada aqui no fórum.

Tópicos do fórum que vc deve tomar conhecimento:

viewtopic.php?f=7&t=3841

viewtopic.php?f=7&t=3784

Um abraço.

Obrigado pelas dicas...

Depois de ler sobre o SOMARPRODUTO vi que ele atende ao que ele quero, no entanto ainda não consegui receber a resposta...

Montei uma nova planilha:
A B C D
material qtdade local data
pilha 1 setor1 11/05/2013
pilha 3 setor1 30/05/2013
cola 5 setor3 12/05/2013
pilha 1 setor2 17/05/2013
pilha 5 setor1 11/04/2013

A12=pilha
A13=setor1

A fórmula é =SOMARPRODUTO(N(A2:A6=A12);N(C2:C6=A13); B2:B6; N(D2:D6>=VALOR(1/5/2013)); N(D2:D6<=VALOR(31/5/2013)))

Mas ta retomando como resposta 0 e deveria ser 4.

Acho que o problema está na parte das datas...

Alguma luz?

Experimente assim:
=SOMARPRODUTO((A2:A6=A12)*(C2:C6=A13)*(D2:D6>=B12)*(D2:D6<=B13)*(B2:B6)) --> onde B12 data inicial e B13 data final
ou
=SOMARPRODUTO((A2:A6=A12)*(C2:C6=A13)*(D2:D6>=DATA.VALOR("01/05/2013"))*(D2:D6<=DATA.VALOR("31/05/2013"))*(B2:B6))

=SOMARPRODUTO(N(A2:A6=A12);N(C2:C6=A13); B2:B6; N(D2:D6>=VALOR(1/5/2013)); N(D2:D6<=VALOR(31/5/2013)))

Desta forma o Excel está calculando a divisão: 1/5/2013 ou 31/5/2013. Leia-se 1 dividido por 5 dividido por 2013. Ou, 31 dividido por 5 dividido por 2013.
isso nao vai funcionar nao...

Idéia: coloque as datas em outras células (F1 e F2 por exemplo), e não use a função Valor(), não precisa.

ou seja, fica assim:

=SOMARPRODUTO(N(A2:A6=A12);N(C2:C6=A13); B2:B6; N(D2:D6>=$F$1); N(D2:D6<=$F$2))

Outra possibilidade, que eu até prefiro, seria você usar o SOMASES():

=SOMASES($B$2:$B$6;$A$2:$A$6;$A$12;$C$2:$C$6;$A$13;$D$2:$D$6;">="&$F$1;$D$2:$D$6;"<="&$F$2)

Agora facilitando a leitura:

=SOMASES($B$2:$B$6;
$A$2:$A$6;$A$12;
$C$2:$C$6;$A$13;
$D$2:$D$6;">="&$F$1;
$D$2:$D$6;"<="&$F$2)

Prefira o SOMASES() caso você vá replicar isso em muitas linhas. Ele é extremamente mais rápido do que o somarproduto() e as somas matriciais.

boa noite,
anexa a plan para analisarmos, tenho dislexia já li uma porção de vezes e ainda não entendi a solicitação.