Caro HICK, bom dia !

Não sei se entendi o que pretende fazer mais dê uma olhadinha no resultado que obtive baseado no seu exemplo.

Meu excel é o 2007 percebi um pouco de compatibilidade na formula mais tente adapitar para a sua necessidade caso tenha algum problema volte ao fórum, o que tiver ao meu alcance te ajudarei.

=SE($G18=115%;PROCV($E18;REGUA115!$A$2:$B$153;2;VERDADEIRO);"")&SE($G18=110%;PROCV(CARTEIRA!$E18;REGUA110!$A$2:$B$91;2;VERDADEIRO);"")&SE(CARTEIRA!$G18=270%;PROCV(CARTEIRA!$E18;REGUA270!$A$2:$B$103;2;VERDADEIRO);"")

Baixe:

Até mais,

Bom dia Rick e Robert

Fiz umas correções nos intervalos e na coluna que deve ser retornada, da fórmula do Robert, e a mesma passou a funcionar:

=SE($G3=115%;PROCV($E3;REGUA115!$A$2:$C$87;3;1);"")&SE($G3=110%;PROCV(CARTEIRA!$E3;REGUA110!$A$2:$C$143;3;1);"")&SE(CARTEIRA!$G3=270%;PROCV(CARTEIRA!$E3;REGUA270!$A$2:$C$103;3;1);"")

Tem dados errados na tua planilha, como por exemplo na "E4" consta 140,21 e na célula "F4" régua 115, mas a planilha da régua 115 só vai até o número 120???
Outra coisa, quando na coluna E tiver erro como #NÚM! o retorno será na coluna "F" também será #NÚM!

Dê retorno.

Se a resposta for útil, clique na mãozinha que fica ao lado da ferramenta Citar.

Um abraço.

Boa tarde Robert e Patropi...

Antes de tudo agradeço a agilidade e presteza com que resolveram a questão.

Observei a fórmula e fiz uma alteração na primeira parte apenas para contemplar as celulas a2:a143 da planilha regua115 e fechou redondo o resultado.
=SE($G3=115%;PROCV($E3;REGUA115!$A$2:$C$143;3;1);"")&

Com relação aos valores maiores Patropi, com essa correção foram solucionados, pois o que ultrapassa os limites da régua trava o resultado em 100 pontos.

Mas ainda resta um problema: a C7 é média aritmética de f30:f33, cujo resultado nao retorna na célula. Tentei incluir a função média na c7 e tbm não retornou o valor.

Outra pergunta: Se eu precisar incluir na planilha mais 5 réguas, como faço para estender a fórmula? Na minha ignorância seria incluir os intervalos abaixo?
SE($G3=101%;PROCV($E3;REGUA101!$A$2:$C$143;3;1);"")&
SE($G3=118%;PROCV($E3;REGUA118!$A$2:$C$143;3;1);"")&
SE($G3=139%;PROCV($E3;REGUA139!$A$2:$C$143;3;1);"")&
SE($G3=143%;PROCV($E3;REGUA143!$A$2:$C$143;3;1);"")&
SE($G3=160%;PROCV($E3;REGUA160!$A$2:$C$143;3;1);"")&

na sequencia ficaria assim:
=SE($G3=115%;PROCV($E3;REGUA115!$A$2:$C$143;3;1);"")&SE($G3=110%;PROCV(CARTEIRA!$E3;REGUA110!$A$2:$C$143;3;1);"")&SE($G3=101%;PROCV($E3;REGUA101!$A$2:$C$143;3;1);"")&SE($G3=118%;PROCV($E3;REGUA118!$A$2:$C$143;3;1);"")&SE($G3=139%;PROCV($E3;REGUA139!$A$2:$C$143;3;1);"")&SE($G3=143%;PROCV($E3;REGUA143!$A$2:$C$143;3;1);"")&SE($G3=160%;PROCV($E3;REGUA160!$A$2:$C$143;3;1);"")&SE(CARTEIRA!$G3=270%;PROCV(CARTEIRA!

Obs.: os valores das novas reguas serão alterados posteriormente.

FORTE ABRAÇO A VOCÊS!

Caro Hick, Boa tarde!

Você disse: Mas ainda resta um problema: a C7 é média aritmética de f30:f33, cujo resultado nao retorna na célula. Tentei incluir a função média na c7 e tbm não retornou o valor.

Também tentei utilizar as funções normais que fazem esse calculo mais não tive êxito.

Utilize essa aqui:

=F30+F31+F32+F33/CONT.VALORES(F30:F33)

Segunda pergunta: na sequencia ficaria assim:
=SE($G3=115%;PROCV($E3;REGUA115!$A$2:$C$143;3;1);"")&SE($G3=110%;PROCV(CARTEIRA!$E3;REGUA110!$A$2:$C$143;3;1);"")&SE($G3=101%;PROCV($E3;REGUA101!$A$2:$C$143;3;1);"")&SE($G3=118%;PROCV($E3;REGUA118!$A$2:$C$143;3;1);"")&SE($G3=139%;PROCV($E3;REGUA139!$A$2:$C$143;3;1);"")&SE($G3=143%;PROCV($E3;REGUA143!$A$2:$C$143;3;1);"")&SE($G3=160%;PROCV($E3;REGUA160!$A$2:$C$143;3;1);"")&SE(CARTEIRA!$G3=270%;PROCV(CARTEIRA!

Sim, na lógica tem que ficar dessa maneira, como você vai ter outro parâmetros .

Tente fazer desta forma se dê errado volte ao fórum que sempre tem alguém disponível para ajudar.

Tomara que eu tenha sido útil?

Até mais,

Robert,
vc não conseguiu utilizar as funções, média pelo fato que o retorno dos "valores de pontos" na coluna "F" serem TEXTO, isso porqu as formulas "se's" não estão aninhadas, mas sim concatenadas, e apesar do retorno se falso ser "" (vazio), ao concatenar o excel interpreta como sendo uma STRING.
Se continuar utilizar a formula concatenada, é necessario "transformar" o valor retornado para numerico; um modo seria:
c7 = {Média(valor(F30>F34))} (matricial);
ou melhor, creio eu, utilizar em F3: (depois copiar para as demais):

=SE($G3=115%;PROCV($E3;REGUA115!$A$2:$B$153;2;VERDADEIRO);SE($G3=110%;PROCV(CARTEIRA!$E3;REGUA110!$A$2:$B$91;2;VERDADEIRO);SE(CARTEIRA!$G3=270%;PROCV(CARTEIRA!$E3;REGUA270!$A$2:$B$103;2;VERDADEIRO);"")))

Revendo a estrutura da planilha, creio ser mais facil utilizar em Fa formula abaixo, assim independentemente de quantas "reguas" forem incluidas,mantendo a mesma regra de nomeação, basta incluir somente o percentual correto:

PROCV($E3;INDIRETO("REGUA" & VALOR(G3*100)&"!$A$2:$B$153");2;VERDADEIRO)

Boa tarde!!

talvez isso também funcione.

=SEERRO(PROCV(E3;INDIRETO("Regua"&G3&"!a1:c200");3;1);"")

arraste para baixo

Bem lembrado Alexandre, pois esqueci o tratamento de erro; apenas um detalhe,
o valor em G3; como está formatado para percentual é 1,15 (visão = 115%), então a necessidade de multiplicar por 100

Reinaldo,

Você disse : vc não conseguiu utilizar as funções, média pelo fato que o retorno dos "valores de pontos" na coluna "F" serem TEXTO,

Brigado pela dica.

Vlw!

Boa noite!!!

Obrigado por clicar na mãozinha, mas você não fez critica, caso sua questão foi solucionada, então para a organização do fórum, marque seu tópico como resolvido!!

Veja como em:
viewtopic.php?f=7&t=3784

Obrigado!!