Erica, se os campos forem "exportados" conforme estão cadastrados (não recebem nenhum caracter adicional), não há necessidade de fazer a "preparação" dos mesmos.
Tb para "mudar" de linha, não é necessario um codigo para cd uma, mas sim atribuir uma variavel à linha que vai se incrementando "automaticamente"
Tem varias maneiras; pode ser assim:

Sub CommandButton1_Click()
    Caminho = ThisWorkbook.Path & Application.PathSeparator
    arquivo = "exportado.txt"
    Open Caminho & arquivo For Output As #1

Worksheets("dados").Activate

linha = 2
    Do While Cells(linha, 1) <> ""
    
        Cpo133 = Application.WorksheetFunction.Rept(0, 7 - Len(Cells(linha, 4))) & _
                               Application.WorksheetFunction.Substitute(Cells(linha, 4), "", "") ' prepara linha 2 coluna 4 e completa com 0
        
        
    Dados = Cells(linha, "A") & Cells(linha, "B") & Cells(linha, "C") & Cpo133 & Cells(linha, "E") & _
    Cells(linha, "F") & Cells(linha, "G") & Cells(linha, "H") & Cells(linha, "I") ' exporta os dados para arquivo txt

    
    Print #1, Dados

    linha = linha + 1
    Loop

    Close
End Sub

Certo consegui fazer algumas adaptações, e agor apreciso de mais uma ajuda, no caso esse codigo começa e exportar a parit da 1° linha e coluna, e se quisesse que começasse a partir A10 por exemplo?

abrigadaa...

Amigo, deu certo consegui é so colocar na linha = 10...

Agora como faço para parar sabe tipo quando chegar na linha 80 ele para, que ai tem outro codigo e outros valores diferentes sabe...

obrigadaaa... e desculpas tantas pergunta.. rsrs

Pode utilizar For .. next ao inves do Do While.. Loop

    Sub CommandButton1_Click()
        Caminho = ThisWorkbook.Path & Application.PathSeparator
        arquivo = "exportado.txt"
        Open Caminho & arquivo For Output As #1

    Worksheets("dados").Activate

  For  linha = 10 to 80 'Aqu determina o inicio da linha e o final
 
            Cpo133 = Application.WorksheetFunction.Rept(0, 7 - Len(Cells(linha, 4))) & _
                                   Application.WorksheetFunction.Substitute(Cells(linha, 4), "", "") ' prepara linha 2 coluna 4 e completa com 0
           
           
        Dados = Cells(linha, "A") & Cells(linha, "B") & Cells(linha, "C") & Cpo133 & Cells(linha, "E") & _
        Cells(linha, "F") & Cells(linha, "G") & Cells(linha, "H") & Cells(linha, "I") ' exporta os dados para arquivo txt

       
        Print #1, Dados

        next

        Close
    End Sub

Perfeitoo.. agardeço... por enquanto é soó muito obrigada...

Boa noite
veja que nao demorei para ter mais duvidas ein rsrs..
fiz umas adaptações e dentre elas tem uma verificação que se nao tiver valor em qualquer linha da coluna A ele nao exporte essa linha, porem ele tambem nao esta exportanto o resto das linhas seguintes onde esta certo. coloquei a planilha anexo com exemplo..

obrigadaaa novamente...

abraços

Boa noite!!

Erica, cumpra as regras do fórum, os arquivos devem ser compactados!!!

O seu arquivo será deletado, favor posta-lo compactado!!

Veja Nossas Regras em:
viewtopic.php?f=7&t=203

Att

Boa noite
veja que nao demorei para ter mais duvidas ein rsrs..
fiz umas adaptações e dentre elas tem uma verificação que se nao tiver valor em qualquer linha da coluna A ele nao exporte essa linha, porem ele tambem nao esta exportanto o resto das linhas seguintes onde esta certo. coloquei a planilha anexo com exemplo..

obrigadaaa novamente...

desculpas ao moderador por nao ter compactado a planilha...

Erica, troque seu código por este abaixo...

Aproveitei para organizar um pouco o código.

Sub CommandButton1_Click()
    Dim UltimaLinha As Long
    Dim Linha As Long
    Dim Caminho As String
    Dim Arquivo As String
    Dim Cpo133 As String
    Dim Dados As String
    
    Caminho = ThisWorkbook.Path & Application.PathSeparator
    Arquivo = "exportado.txt"
    Open Caminho & Arquivo For Output As #1

    Worksheets("dados").Activate

    UltimaLinha = Range("A" & Rows.Count).End(xlUp).Row
    
    For Linha = 2 To UltimaLinha
        Cpo133 = String(7 - Len(Cells(Linha, 4)), "0") & Cells(Linha, 4)
        Dados = Cells(Linha, "A") & Cells(Linha, "B") & Cells(Linha, "C") & Cpo133 & Cells(Linha, "E") & _
        Cells(Linha, "F") & Cells(Linha, "G") & Cells(Linha, "H") & Cells(Linha, "I") ' exporta os dados para arquivo txt
        Print #1, Dados
    Next
    Close #1
End Sub

bom dia
porem, ele exporta o restante da linha, tem como nao exportar a linha inteira em que nao tinha o valor....

Desculpe... tinha esquecido de colocar uma condicional:

Sub CommandButton1_Click()
    Dim UltimaLinha As Long
    Dim Linha As Long
    Dim Caminho As String
    Dim Arquivo As String
    Dim Cpo133 As String
    Dim Dados As String
   
    Caminho = ThisWorkbook.Path & Application.PathSeparator
    Arquivo = "exportado.txt"
    Open Caminho & Arquivo For Output As #1

    Worksheets("dados").Activate

    UltimaLinha = Range("A" & Rows.Count).End(xlUp).Row
   
    For Linha = 2 To UltimaLinha
        If Cells(Linha, 1) <> "" Then
            Cpo133 = String(7 - Len(Cells(Linha, 4)), "0") & Cells(Linha, 4)
            Dados = Cells(Linha, "A") & Cells(Linha, "B") & Cells(Linha, "C") & Cpo133 & Cells(Linha, "E") & _
            Cells(Linha, "F") & Cells(Linha, "G") & Cells(Linha, "H") & Cells(Linha, "I") ' exporta os dados para arquivo txt
            Print #1, Dados
        End If
    Next
    Close #1
End Sub

obrigadaaa...

ficou otimo..