Bomdia!!

Use apenas uma formuala

=C1=[Relatório2.xls]Relatório!$B$1

Att

Desculpe Alexandre mas acho que não fiz certo porque só a primeira linha deu verdadeiro e as demais falso embora hajam dados iguais. E considerando que eu tenha feito errado esta formula retorna a resposta correta se dados semelhantes estiverem em linhas diferentes?

Segue a planilha com a sua ideia para conferir se fiz certo.

Obrigado!

Bom dia!!

Se por ventura os dados não for igual para o excel (Ex:. espaços no início ou no final, formatos diferentes etc), os dados não irão coincidir se.

Caso queira por intermedio do VBA, certifique se de que os arquivo estão equiparados (nomes das guias iguais e estrutura de dados iguais, com colunas etc), ambos os arquivos devem está abertos!!

Sub AleVBA_20419()

    Dim wbkComp As Workbook
    Dim wbkWith As Workbook
    Dim wbkDiff As Workbook
    Dim shtComp As Worksheet
    Dim shtWith As Worksheet
    Dim shtDiff As Worksheet
    Dim lngCompRow As Long
    Dim lngDiffRow As Long
    Dim blnSame As Boolean
    Dim intCol As Integer
     
    Set wbkComp = Workbooks("Relatório1.xls")
    Set wbkWith = Workbooks("Relatório2.xls")
    Set wbkDiff = Workbooks.Add
     
    For Each shtComp In wbkComp.Worksheets
        Application.StatusBar = "Verificando " & shtComp.Name
        Set shtWith = wbkWith.Worksheets(shtComp.Name)
        Set shtDiff = wbkDiff.Worksheets.Add
        shtDiff.Name = "Diferença " & shtComp.Name
        lngCompRow = 1
        lngDiffRow = 1
        Do While shtComp.Cells(lngCompRow, 1) <> ""
            blnSame = True
            For intCol = 1 To 2 'Compara as colunas A e B de cada arquivo
                If shtComp.Cells(lngCompRow, intCol) <> shtWith.Cells(lngCompRow, intCol) Then
                    blnSame = False
                    Exit For
                End If
            Next
            If Not blnSame Then
                shtComp.Rows(lngCompRow).Copy shtDiff.Cells(lngDiffRow, 1)
                lngDiffRow = lngDiffRow + 1
            End If
            lngCompRow = lngCompRow + 1
        Loop
    Next
    Application.StatusBar = False
End Sub

Att

Eu vou montar um modelo seguindo o seu código ( a falta de prática me fará demorar um pouco rsrsrs...) e assim que o fizer entro em contato.

Agradeço já antecipadamente o tempo que está gastando comigo.