Bom dia xandrinho,

Tenta assim:

Private Sub CommandButton1_Click()
'define variáveis para tratar a pesquisa
Dim wsAtiva     As Worksheet
Dim Ultl        As Long
Dim i           As Long
Dim contador    As Integer

    'Define a worksheet ativa e identifica a última linha
    Set wsAtiva = ThisWorkbook.ActiveSheet
    Ultl = wsAtiva.Cells(Rows.Count, 1).End(xlUp).Row
    
    'verifica se o TextBox1 é diferente (<>) de vazio
    If TextBox1.Text = Empty Then Call preencherListBox: Exit Sub
    
    'atribui o valor zero ao contador
    contador = 0
     
    'Limpa a listbox1
    Me.ListBox1.Clear
    
    'Inicia o loop com a verificação do início do texto procurado
    For i = 2 To Ultl
        If UCase(wsAtiva.Cells(i, 1).Value) Like UCase(TextBox1.Value) & "*" Then
            Me.ListBox1.AddItem wsAtiva.Cells(i, 1).Value
            Me.ListBox1.List(contador, 1) = wsAtiva.Cells(i, 2).Value
            contador = contador + 1
        End If
    Next i
    
    'Verifica a quantidade de resultados encontrados
    If contador = 0 Then
        MsgBox "Nenhum registro encontrado", vbCritical, "Erro"
        Me.ListBox1.Clear
        Call preencherListBox
        Me.TextBox1.Value = Empty
        Me.TextBox1.SetFocus
    End If
    
    'Libera memória
    Set wsAtiva = Nothing

End Sub

Qualquer coisa da o grito.
Abraço

Bernado, Mto Show, era exatamente isto que precisava. Só um detalhe, qdo acionado o botão restaura, o mesmo não esta limpando para nova pesquisa, consegue me ajudar ainda neste detalhe?

Cara, o botão de restaurar está normal.
O que notei agora é que ao clicar em "Pesquisar" com o campo "Nome" vazio, ele vai preenchendo. Basta limpar antes de preencher.

Private Sub CommandButton1_Click()
'define variáveis para tratar a pesquisa
Dim wsAtiva     As Worksheet
Dim Ultl        As Long
Dim i           As Long
Dim contador    As Integer

    'Define a worksheet ativa e identifica a última linha
    Set wsAtiva = ThisWorkbook.ActiveSheet
    Ultl = wsAtiva.Cells(Rows.Count, 1).End(xlUp).Row
    
    'Limpa a listbox1
    Me.ListBox1.Clear
    
    'verifica se o TextBox1 é diferente (<>) de vazio
    If TextBox1.Text = Empty Then Call preencherListBox: Exit Sub
    
    'atribui o valor zero ao contador
    contador = 0
    
    'Inicia o loop com a verificação do início do texto procurado
    For i = 2 To Ultl
        If UCase(wsAtiva.Cells(i, 1).Value) Like UCase(TextBox1.Value) & "*" Then
            Me.ListBox1.AddItem wsAtiva.Cells(i, 1).Value
            Me.ListBox1.List(contador, 1) = wsAtiva.Cells(i, 2).Value
            contador = contador + 1
        End If
    Next i
    
    'Verifica a quantidade de resultados encontrados
    If contador = 0 Then
        MsgBox "Nenhum registro encontrado", vbCritical, "Erro"
        Me.ListBox1.Clear
        Call preencherListBox
        Me.TextBox1.Value = Empty
        Me.TextBox1.SetFocus
    End If
    
    'Libera memória
    Set wsAtiva = Nothing

End Sub

Qualquer coisa da o grito.
Abraço

Mestre Bernado!!!!
Ok, Mto Obrigado!!
Deixa eu tentar aproveitar a sua bondade, aumentei o intervalo da pesquisa que vai da coluna A até a Coluna L, porem as informações da planilha, não são exibidas na Listbox. Poderia por favor, me ajudar só mais nesta questão?
De ante mão já te agradeço por toda paciência....

Cara, o listbox tem um limite de 10 colunas.

Valeu Bernardo, Mto Obrigado, pela paciência e ajuda.

Forte Abraço.