Amigo,
Essas informações da Coluna A vem da onde?? se for de uma outra formulá usa a formula =èerros()
pois ai você consegue tratar esse Valor caso ele seja um erro.

Média ignorando os erros:

=MÉDIA(SE(NÃO(ÉERROS(A2:A98));A2:A98))

Média ignorando os erros e os zeros:

=MÉDIA(SE(SE(NÃO(ÉERROS(A2:A98));A2:A98)*1>0;A2:A98))

Ambas as fórmulas são matriciais, finaliza-las com "Ctrl + Shift + Enter"

Qualquer coisa da o grito...

Se vc quiser saber a média de Janeiro vc pode usar assim
=MÉDIASES(A2:A500;B2:B500;">=01/01/2011";B2:B500;"<=31/01/2011")

Para fazer com os outros meses é só trocar as datas...
é isso mesmo que vc precisava?

axo q tdo mundo postou junto

nao vi que havia erros na coluna!!!

Se vc quiser saber a média de Janeiro vc pode usar assim
=MÉDIASES(A2:A500;B2:B500;">=01/01/2011";B2:B500;"<=31/01/2011")

Para fazer com os outros meses é só trocar as datas...
é isso mesmo que vc precisava?

Deu certo, mais na hora que chegou no mes de junho tem #VALOR! na linha dai ja não sai a média.

acrescentar algo nesta formula.. modo que mesmo que tiver #VALOR! ela ignore e calcule o restante?

muito obrigado mesmo pela ajuda.

Média ignorando os erros por mês:
=MÉDIA(SE((NÃO(ÉERROS(A2:A98)))*(MÊS(B2:B98)=7);A2:A98))

Média ignorando os erros e os zeros por mês:
=MÉDIA(SE((SE(NÃO(ÉERROS(A2:A98));A2:A98)*1>0)*(MÊS(B2:B98)=7);A2:A98))

Ambas as fórmulas são matriciais, finaliza-las com Ctrl + Shift + Enter

Qualquer coisa da o grito...

Bernardo,Aproveitando esse tópico
preciso fazer uma média simples porém do meio dos meus dados exite um erro #VALOR!, como eu faço a média deixando esse erro de lado.
coloquei um exemplo.; Excel 2003
Na minha soma funcionou =SOMASE(E25:AI25;"<>#VALOR!";E25:AI25) porém minha média que não sei como fazer

Fernando, você não testou nada que eu postei né...

o da soma, você pode deixar somente assim:
=SOMASE(B2:AF2;"<>#VALOR!")

se sua versão do Ofice for 2007 ou superior, você pode fazer o da média assim:
=MÉDIASE(B2:AF2;"<>#VALOR!")

Caso não seja 2007, tem de usar matricial:
=MÉDIA(SE(NÃO(ÉERROS(B2:AF2));B2:AF2))
Ctrl + Shift + Enter

Funciona também com a soma em ambas as versões:
=SOMA(SE(NÃO(ÉERROS(B2:AF2));B2:AF2))
Ctrl + Shift + Enter

Mas quanto menos matricial puder usar, é melhor, pois a velocidade de cálculo de uma matricial é mais demorada comparada ao cálculo de uma fórmula interna do Excel.

Segue em anexo um exemplo

Qualquer coisa da o grito...

...rs
Pior que tinha testado, porém não tinha visto o detalhe que era Matricial.

valeu Brother!

Tranquilo...

Qualquer coisa da o grito...

Média ignorando os erros por mês:
=MÉDIA(SE((NÃO(ÉERROS(A2:A98)))*(MÊS(B2:B98)=7);A2:A98))

Média ignorando os erros e os zeros por mês:
=MÉDIA(SE((SE(NÃO(ÉERROS(A2:A98));A2:A98)*1>0)*(MÊS(B2:B98)=7);A2:A98))

Ambas as fórmulas são matriciais, finaliza-las com Ctrl + Shift + Enter

Qualquer coisa da o grito...

Bernardo tentei as formulas que você me passou... mais não deu muito certo.. se puder me ajudar... pelo que notei.. quanto tem alguma celulá em branco ele já nao faz a formula direito... no campo de data você vai perceber que vai estar em branco a partir do 100 se eu nao me engano...

o porque disso é pq quando vou abrindo nao conformidades vai vinculando com esta celular.

se você conseguir me ajudar agradeço.

Marcao, não foi nem por causa do erro, pois esse caso ele já estava tratando...
foi o intervalo da data em branco

tenta assim:

Média:

=MÉDIA(SE((NÃO(ÉERROS(A2:A201)))*(MÊS(SE(B2:B201<>"";B2:B201))=7);A2:A201))

Média ignorando zero:

=MÉDIA(SE((SE(NÃO(ÉERROS(A2:A201));A2:A201)*1>0)*(MÊS(SE(B2:B201<>"";B2:B201))=7);A2:A201))

Qualquer coisa da o grito...

Valew Bernardo não sei nem como agradecer você cara... muito bom... um dia vou ficar bom deste jeito no excel. rsrs

Para finalizar com tudo... vi no topico anterior que vc disse que para versão de excel 2007 nao precisa daquele shift+ctrl+enter...

Eu uso o office 2007, como ficaria a formula?

Caso não der certo também não esquenta... só por curiosidade.

Como coloco o simbolo 6 para conclusão de ajuda? Eu somente conseguir editar este ultimo post meu, o primeiro quando criei a msg não conseguir colocar o icone 6

Marcao, o 2007 tem a função mediases(), tenta assim:

média:

=MÉDIASES(A2:A201;B2:B201;">="&"1/7/2011";B2:B201;"<"&"1/8/2011";A2:A201;"<>#VALOR!")

média ignorando zero:

=MÉDIASES(A2:A201;B2:B201;">="&"1/7/2011";B2:B201;"<"&"1/8/2011";A2:A201;"<>#VALOR!";A2:A201;">0")

Sem precisar finalizar com Ctrl + Shift + Enter

Preoculpa não cara, é só participar do fórum que você pega a manha rapidinho...
Não sei se é isso, mas o fórum está em manutenção, depois o Eron da uma olhada...
vou arrumar para você...

Qualquer coisa da o grito...