Cacá, Bom Dia.

Eu alterei para que a formula tenha o primeiro dia útil automaticamente, confere.

Se foi útil, clique na mãozinha que fica do lado da ferramenta Citar, é uma forma de agradecimento

Decio

Bom dia.
Você tentou SOMASE desta forma?
Célula B18 =SOMASE($B$3:$F$3;B3;$B$5:$F$5)+SOMASE($B$7:$F$7;D7;$B$9:$F$9)+SOMASE($B$11:$F$11;C11;$B$13:$F$13)
Arraste até F18.

Fiz de uma forma melhor, mas siga as instruções de formatação personalizada na planilha anexa.

E os feriados?

Pessoal, eu aproveitei a ideia de usar a lista de datas, em forma matricial. Lembram que numa aula dessas por aí... eu ensinei a usar o LIN(INDIRETO()) e assim obter a lista de datas? Então, de posse da lista de dias de cada mes, eu pude identificar quais são finais de semana, pude excluir quais são feriados, e a matriz final, peguei o menor dia disponível, e a partir dele, usei o DIATRABALHO() para os dias úteis seguintes...

Assim eu consegui alinhar os primeiros 5 dias úteis de cada mês *(e poderia ir até o último...)

Ou seja, eu quebrei sua lógica e montei uma melhorzinha. Como estou usando 2010, não tinha o mínimoses(), o que provavelmente tornaria a fórmula menor.
Ok, dito tudo isso, vamos lá.

O anexo aqui:

Explicando:
Primeiro, eu puxei uma lista de feriados a partir de um tópico meu daqui mesmo (viewtopic.php?f=21&t=15313).
Coloquei a lista no arquivo e a nomeei de Feriados, intervalo dinâmico usando DESLOC().

Em seguida, eliminei colunas e linhas inúteis do seu modelo, rs

Para identificar o mês de março na célula A2, eu usei:

=FIMMÊS(HOJE();-4)+1

Para identificar o mês de abril na célula A5, eu usei:

=FIMMÊS(HOJE();-3)+1

Para identificar o mês de maio na célula A8, eu usei:

=FIMMÊS(HOJE();-2)+1

Para identificar o mês de junho na célula A11, eu usei:

=FIMMÊS(HOJE();-1)+1

Em seguida, na célula B2, eu coloquei a seguinte fórmula MATRICIAL, para identificar o primeiro dia útil do mês de março:

=MENOR(SE(LIN(INDIRETO($A2&":"&FIMMÊS($A2;0)))*
--(DIA.DA.SEMANA(LIN(INDIRETO($A2&":"&FIMMÊS($A2;0)));2)<=5)*
--(SE(ÉERROS(CORRESP(LIN(INDIRETO($A2&":"&FIMMÊS($A2;0)));Feriados;0));1;0))=0;FALSO;
LIN(INDIRETO($A2&":"&FIMMÊS($A2;0)))*
--(DIA.DA.SEMANA(LIN(INDIRETO($A2&":"&FIMMÊS($A2;0)));2)<=5)*
--(SE(ÉERROS(CORRESP(LIN(INDIRETO($A2&":"&FIMMÊS($A2;0)));Feriados;0));1;0)));1)

Copiei esta fórmula matricial e colei em B5, B8 e B11.

Claro que há mil maneiras de preparar Neston, ou seja, se não quiser matricial, use essa:

=DIATRABALHO(FIMMÊS(A2;-1);1;Feriados)

Copiei esta fórmula matricial e colei em B5, B8 e B11.

No intervalo C2:F2, usei esta fórmula:

=DIATRABALHO(B2;1;Feriados)

Copiei esta fórmula e colei nas células C2, C8 e C11.

E agora, finalizando, coloquei a soma simples no mês de junho. Ou seja, a fórmula:
=B3+B6+B9
e na parte da média:
=b12/3

Bom dia, pessoal!

Vocês ajudaram demais!! Entenderam a minha dúvida e melhoraram a minha planilha e este probleminha que eu estava
Agradeço a atenção nas respostas do Estevao e a pergunta/resposta/explicação do Fernando foram excelentes!

Muito obrigada pelo nível na contribuição e nas explicações!

Vou usar mais e recomendar o fórum porque é uma excelente fonte de conhecimento.

Abraços!